381 lines
14 KiB
Plaintext
381 lines
14 KiB
Plaintext
; AutoPercenty3 Inno Setup Script
|
|
; 이 스크립트는 cx_Freeze로 빌드된 결과물이 있는 "build\exe.win-amd64-3.11" 폴더를 기반으로 인스톨러를 제작합니다.
|
|
; 20260226_095138에 생성됨
|
|
|
|
#define AppId "autopercenty"
|
|
#define MyAppName "Edit_PartTimer"
|
|
#define MyAppVersion "3.13.1"
|
|
#define MyAppPublisher "WhenRideMyCar"
|
|
#define MyAppProgramName "편집알바생"
|
|
#define MyAppDescription "편집알바생"
|
|
#define MyAppCopyright "Copyright 2024"
|
|
#define MyAppExeName "Edit_PartTimer3"
|
|
#define MySetupName "Edit_PartTimer Setup"
|
|
#define MySetupIcon "src/Edit_PartTimer3.ico"
|
|
#define MySetupOutputDir "dist/installer"
|
|
|
|
[Setup]
|
|
; 기본 설정
|
|
AppId={#AppId}
|
|
AppName={#MyAppProgramName}
|
|
AppVersion={#MyAppVersion}
|
|
AppPublisher={#MyAppPublisher}
|
|
DefaultDirName={autopf}\{#MyAppName}
|
|
DefaultGroupName={#MyAppPublisher}
|
|
OutputDir={#MySetupOutputDir}
|
|
OutputBaseFilename={#MySetupName}
|
|
SetupIconFile={#MySetupIcon}
|
|
Compression=lzma
|
|
SolidCompression=yes
|
|
|
|
; 업데이트 관련 설정 - 권한 최적화
|
|
PrivilegesRequired=admin
|
|
PrivilegesRequiredOverridesAllowed=dialog
|
|
UpdateUninstallLogAppName=yes
|
|
AppMutex={#MyAppName}
|
|
CloseApplications=yes
|
|
RestartApplications=no
|
|
|
|
; 보안 및 호환성 설정
|
|
ArchitecturesAllowed=x64
|
|
ArchitecturesInstallIn64BitMode=x64
|
|
AllowNoIcons=yes
|
|
|
|
; 버전 정보
|
|
VersionInfoVersion={#MyAppVersion}
|
|
VersionInfoCompany={#MyAppPublisher}
|
|
VersionInfoDescription={#MyAppDescription}
|
|
VersionInfoCopyright={#MyAppCopyright}
|
|
VersionInfoProductName={#MyAppProgramName}
|
|
VersionInfoProductVersion={#MyAppVersion}
|
|
|
|
[Languages]
|
|
Name: "korean"; MessagesFile: "compiler:Languages\Korean.isl"
|
|
|
|
[Tasks]
|
|
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"
|
|
|
|
[Dirs]
|
|
; 설치 시 {app}\logs 폴더를 생성하고,
|
|
; Users 그룹에 'modify' 권한(=쓰기 가능)을 부여
|
|
Name: "{app}\logs"; Permissions: users-modify
|
|
; 설치 시 {app}\user_data 폴더를 생성하고,
|
|
; Users 그룹에 'modify' 권한(=쓰기 가능)을 부여
|
|
Name: "{app}\user_data"; Permissions: users-modify
|
|
; Playwright 브라우저 폴더를 Program Files 내부에 생성
|
|
Name: "{app}\lib\src\browsers\chromium-1200"; Permissions: users-modify
|
|
; Playwright 브라우저 사용자폴더를 Program Files 내부에 생성
|
|
Name: "{app}\lib\src\browsers\user_data"; Permissions: users-modify
|
|
|
|
[Files]
|
|
; 프로그램 파일만 설치 (항상 덮어쓰기)
|
|
Source: "build\exe.win-amd64-3.11\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs
|
|
; updater.exe 파일 포함 (업데이트 관리자)
|
|
Source: "updater.exe"; DestDir: "{app}"; Flags: ignoreversion
|
|
; VC++ 재배포 패키지 파일을 임시 폴더({tmp})에 복사
|
|
Source: "VC_redist.x64.exe"; DestDir: "{tmp}"; Flags: deleteafterinstall
|
|
|
|
[Registry]
|
|
; Playwright 브라우저 경로를 Program Files 내부로 설정
|
|
Root: HKCU; Subkey: "Environment"; ValueType: expandsz; ValueName: "PLAYWRIGHT_BROWSERS_PATH"; ValueData: "{app}\lib\src\browsers"; Flags: preservestringtype
|
|
|
|
[Icons]
|
|
; 시작 메뉴 바로가기
|
|
Name: "{group}\{#MyAppProgramName}"; Filename: "{app}\{#MyAppExeName}.exe"
|
|
; 바탕화면 바로가기
|
|
Name: "{autodesktop}\{#MyAppProgramName}"; Filename: "{app}\{#MyAppExeName}.exe"; Tasks: desktopicon
|
|
; 프로그램 제거 바로가기
|
|
Name: "{group}\{#MyAppProgramName} 제거"; Filename: "{uninstallexe}"
|
|
|
|
[Run]
|
|
; VC++ 재배포 패키지 설치 (필요할 경우)
|
|
Filename: "{tmp}\VC_redist.x64.exe"; Parameters: "/install /passive /norestart"; StatusMsg: "VC++ 재배포 패키지 설치 중..."; Check: NeedsVCredist
|
|
; 설치 후 프로그램 실행 (원할 경우)
|
|
Filename: "{app}\{#MyAppExeName}.exe"; Description: "{cm:LaunchProgram,{#MyAppProgramName}}"; Flags: nowait postinstall skipifsilent
|
|
|
|
[Code]
|
|
function CompareVersion(V1, V2: string): Integer;
|
|
var
|
|
P1, P2, N1, N2: Integer;
|
|
begin
|
|
P1 := 1;
|
|
P2 := 1;
|
|
Result := 0;
|
|
while (Result = 0) and ((P1 <= Length(V1)) or (P2 <= Length(V2))) do begin
|
|
while (P1 <= Length(V1)) and (V1[P1] = '.') do Inc(P1);
|
|
while (P2 <= Length(V2)) and (V2[P2] = '.') do Inc(P2);
|
|
if (P1 <= Length(V1)) and (P2 <= Length(V2)) then begin
|
|
N1 := 0; while (P1 <= Length(V1)) and (V1[P1] >= '0') and (V1[P1] <= '9') do begin N1 := N1 * 10 + Ord(V1[P1]) - Ord('0'); Inc(P1); end;
|
|
N2 := 0; while (P2 <= Length(V2)) and (V2[P2] >= '0') and (V2[P2] <= '9') do begin N2 := N2 * 10 + Ord(V2[P2]) - Ord('0'); Inc(P2); end;
|
|
if N1 < N2 then Result := -1 else if N1 > N2 then Result := 1;
|
|
end else begin
|
|
if P1 <= Length(V1) then Result := 1 else if P2 <= Length(V2) then Result := -1;
|
|
end;
|
|
while (P1 <= Length(V1)) and (V1[P1] <> '.') do Inc(P1);
|
|
while (P2 <= Length(V2)) and (V2[P2] <> '.') do Inc(P2);
|
|
end;
|
|
end;
|
|
|
|
// 파일 또는 폴더 복사 함수
|
|
procedure CopyDir(const SourcePath, DestPath: string);
|
|
var
|
|
FindRec: TFindRec;
|
|
SourceFilePath: string;
|
|
DestFilePath: string;
|
|
begin
|
|
ForceDirectories(DestPath);
|
|
|
|
if FindFirst(SourcePath + '\*', FindRec) then
|
|
begin
|
|
try
|
|
repeat
|
|
if (FindRec.Name <> '.') and (FindRec.Name <> '..') then
|
|
begin
|
|
SourceFilePath := SourcePath + '\' + FindRec.Name;
|
|
DestFilePath := DestPath + '\' + FindRec.Name;
|
|
|
|
if FindRec.Attributes and FILE_ATTRIBUTE_DIRECTORY = 0 then
|
|
begin
|
|
if FileCopy(SourceFilePath, DestFilePath, False) then
|
|
Log('파일 복사 성공: ' + SourceFilePath + ' -> ' + DestFilePath)
|
|
else
|
|
Log('파일 복사 실패: ' + SourceFilePath);
|
|
end
|
|
else
|
|
CopyDir(SourceFilePath, DestFilePath);
|
|
end;
|
|
until not FindNext(FindRec);
|
|
finally
|
|
FindClose(FindRec);
|
|
end;
|
|
end;
|
|
end;
|
|
|
|
// 디렉토리 삭제 함수
|
|
procedure DeleteDir(const DirPath: string);
|
|
var
|
|
FindRec: TFindRec;
|
|
FilePath: string;
|
|
begin
|
|
if not DirExists(DirPath) then Exit;
|
|
|
|
if FindFirst(DirPath + '\*', FindRec) then
|
|
begin
|
|
try
|
|
repeat
|
|
if (FindRec.Name <> '.') and (FindRec.Name <> '..') then
|
|
begin
|
|
FilePath := DirPath + '\' + FindRec.Name;
|
|
|
|
if FindRec.Attributes and FILE_ATTRIBUTE_DIRECTORY = 0 then
|
|
begin
|
|
if DeleteFile(FilePath) then
|
|
Log('파일 삭제 성공: ' + FilePath)
|
|
else
|
|
Log('파일 삭제 실패: ' + FilePath);
|
|
end
|
|
else
|
|
DeleteDir(FilePath);
|
|
end;
|
|
until not FindNext(FindRec);
|
|
finally
|
|
FindClose(FindRec);
|
|
end;
|
|
end;
|
|
|
|
if RemoveDir(DirPath) then
|
|
Log('디렉토리 삭제 성공: ' + DirPath)
|
|
else
|
|
Log('디렉토리 삭제 실패: ' + DirPath);
|
|
end;
|
|
|
|
// 프로그램 실행 여부 확인
|
|
function IsAppRunning(const FileName: string): Boolean;
|
|
var
|
|
Handle: THandle;
|
|
begin
|
|
Handle := FindWindowByWindowName('{#MyAppProgramName}'); // 프로그램의 윈도우 타이틀로 찾기
|
|
Result := (Handle <> 0);
|
|
end;
|
|
|
|
// 프로그램 종료
|
|
procedure CloseApplication(const FileName: string);
|
|
var
|
|
Handle: THandle;
|
|
begin
|
|
Handle := FindWindowByWindowName('{#MyAppProgramName}');
|
|
if Handle <> 0 then
|
|
begin
|
|
PostMessage(Handle, 18, 0, 0); // WM_QUIT
|
|
Sleep(1000); // 종료 대기
|
|
end;
|
|
end;
|
|
|
|
// VC++ 재배포 패키지 필요 여부 확인
|
|
function NeedsVCredist: Boolean;
|
|
begin
|
|
if RegKeyExists(HKEY_LOCAL_MACHINE, 'SOFTWARE\Microsoft\VisualStudio\14.0\VC\Runtimes\x64') then
|
|
Result := False // 이미 설치됨
|
|
else
|
|
Result := True; // 미설치 -> 설치 필요
|
|
end;
|
|
|
|
// 설치 완료 후 실행 여부 확인
|
|
function InitializeFinish(): Boolean;
|
|
var
|
|
ResultCode: Integer;
|
|
begin
|
|
Result := True;
|
|
if MsgBox('설치가 완료되었습니다. 프로그램을 실행하시겠습니까?' + #13#10 +
|
|
'(실행 시 서버와 동기화하여 설정이 업데이트됩니다)',
|
|
mbConfirmation, MB_YESNO) = IDYES then
|
|
begin
|
|
Exec(ExpandConstant('{app}\{#MyAppExeName}.exe'), '', '', SW_SHOW, ewNoWait, ResultCode);
|
|
end;
|
|
end;
|
|
|
|
function InitializeSetup(): Boolean;
|
|
var
|
|
OldVersion: String;
|
|
NewVersion: String;
|
|
OldAppPath: String;
|
|
UserDataSourcePath, UserDataBackupPath: String;
|
|
LibSrcPath: String;
|
|
ResultCode: Integer;
|
|
begin
|
|
Result := True;
|
|
NewVersion := '{#MyAppVersion}';
|
|
UserDataBackupPath := ExpandConstant('{tmp}\user_data_backup');
|
|
|
|
// 현재 프로그램 버전 확인
|
|
if RegQueryStringValue(HKLM, 'Software\Microsoft\Windows\CurrentVersion\Uninstall\{#MyAppName}_is1',
|
|
'DisplayVersion', OldVersion) then
|
|
begin
|
|
// 같은 버전이거나 더 높은 버전이 설치되어 있는 경우
|
|
if CompareVersion(OldVersion, NewVersion) >= 0 then
|
|
begin
|
|
MsgBox('현재 설치된 버전(' + OldVersion + ')이 이 설치 프로그램의 버전(' +
|
|
NewVersion + ')과 같거나 더 높습니다.' + #13#10 +
|
|
'설치를 계속할 수 없습니다.', mbInformation, MB_OK);
|
|
Result := False;
|
|
exit;
|
|
end;
|
|
|
|
// 이전 버전이 설치되어 있는 경우 업데이트 진행
|
|
if CompareVersion(OldVersion, NewVersion) < 0 then
|
|
begin
|
|
Log('업데이트 설치 진행: ' + OldVersion + ' -> ' + NewVersion);
|
|
|
|
// 프로그램이 실행 중인지 확인하고 종료 요청
|
|
if IsAppRunning('{#MyAppExeName}.exe') then
|
|
begin
|
|
if MsgBox('프로그램을 업데이트하기 위해 실행 중인 프로그램을 종료해야 합니다.' + #13#10 +
|
|
'계속하시겠습니까?', mbConfirmation, MB_YESNO) = IDNO then
|
|
begin
|
|
Result := False;
|
|
exit;
|
|
end;
|
|
CloseApplication('{#MyAppExeName}.exe');
|
|
Sleep(2000); // 프로세스 종료 대기
|
|
|
|
// 프로세스가 여전히 실행 중이면 강제 종료
|
|
Log('프로세스 강제 종료 시도: {#MyAppExeName}.exe');
|
|
Exec('taskkill', '/f /im {#MyAppExeName}.exe /t', '', SW_HIDE, ewWaitUntilTerminated, ResultCode);
|
|
Sleep(3000); // 강제 종료 후 추가 대기
|
|
end;
|
|
|
|
// 레지스트리에서 설치 경로 확인
|
|
if RegQueryStringValue(HKLM, 'Software\Microsoft\Windows\CurrentVersion\Uninstall\{#MyAppName}_is1',
|
|
'InstallLocation', OldAppPath) then
|
|
begin
|
|
Log('기존 설치 경로: ' + OldAppPath);
|
|
|
|
// lib/src/user_data 폴더 백업
|
|
UserDataSourcePath := OldAppPath + '\lib\src\user_data';
|
|
if DirExists(UserDataSourcePath) then
|
|
begin
|
|
Log('사용자 데이터 백업 중: ' + UserDataSourcePath + ' -> ' + UserDataBackupPath);
|
|
ForceDirectories(UserDataBackupPath);
|
|
CopyDir(UserDataSourcePath, UserDataBackupPath);
|
|
end
|
|
else
|
|
begin
|
|
Log('사용자 데이터 폴더가 존재하지 않음: ' + UserDataSourcePath);
|
|
end;
|
|
|
|
// 기존 설치 폴더 완전 삭제 (사용자 데이터는 이미 백업됨)
|
|
if DirExists(OldAppPath) then
|
|
begin
|
|
Log('기존 설치 폴더 삭제 중: ' + OldAppPath);
|
|
|
|
// 1차 시도: Inno Setup 내장 함수
|
|
DeleteDir(OldAppPath);
|
|
|
|
// 삭제 확인 및 재시도
|
|
Sleep(2000); // 2초 대기
|
|
if DirExists(OldAppPath) then
|
|
begin
|
|
Log('설치 폴더 삭제 재시도 (Windows 명령어 사용): ' + OldAppPath);
|
|
// Windows rmdir 명령어로 강제 삭제 시도
|
|
Exec('cmd.exe', '/c rmdir /s /q "' + OldAppPath + '"', '', SW_HIDE, ewWaitUntilTerminated, ResultCode);
|
|
Sleep(2000); // 추가 대기
|
|
end;
|
|
|
|
// 3차 시도: PowerShell로 강제 삭제
|
|
if DirExists(OldAppPath) then
|
|
begin
|
|
Log('설치 폴더 삭제 3차 시도 (PowerShell 사용): ' + OldAppPath);
|
|
Exec('powershell.exe', '-Command "Remove-Item -Path ''' + OldAppPath + ''' -Recurse -Force -ErrorAction SilentlyContinue"', '', SW_HIDE, ewWaitUntilTerminated, ResultCode);
|
|
Sleep(2000);
|
|
end;
|
|
|
|
// 여전히 존재하면 사용자에게 알림
|
|
if DirExists(OldAppPath) then
|
|
begin
|
|
Log('경고: 설치 폴더 삭제 실패 - 일부 파일이 사용 중이거나 권한 문제일 수 있음: ' + OldAppPath);
|
|
if MsgBox('기존 설치 폴더를 완전히 삭제하지 못했습니다.' + #13#10 +
|
|
'이전 버전의 파일들이 남아있어 새 버전과 충돌할 수 있습니다.' + #13#10 + #13#10 +
|
|
'폴더: ' + OldAppPath + #13#10 + #13#10 +
|
|
'설치를 계속하시겠습니까?' + #13#10 +
|
|
'(아니오를 선택하면 수동으로 폴더를 삭제한 후 다시 설치하세요)',
|
|
mbConfirmation, MB_YESNO) = IDNO then
|
|
begin
|
|
Result := False;
|
|
exit;
|
|
end;
|
|
end
|
|
else
|
|
begin
|
|
Log('기존 설치 폴더 삭제 완료: ' + OldAppPath);
|
|
end;
|
|
end
|
|
else
|
|
begin
|
|
Log('삭제할 설치 폴더가 존재하지 않음: ' + OldAppPath);
|
|
end;
|
|
end;
|
|
end;
|
|
end;
|
|
end;
|
|
|
|
procedure CurStepChanged(CurStep: TSetupStep);
|
|
var
|
|
UserDataBackupPath, UserDataDestPath: String;
|
|
begin
|
|
// 설치 완료 후
|
|
if CurStep = ssPostInstall then
|
|
begin
|
|
UserDataBackupPath := ExpandConstant('{tmp}\user_data_backup');
|
|
UserDataDestPath := ExpandConstant('{app}\lib\src\user_data');
|
|
|
|
// 백업한 사용자 데이터 폴더가 있으면 복원
|
|
if DirExists(UserDataBackupPath) then
|
|
begin
|
|
Log('사용자 데이터 복원 중: ' + UserDataBackupPath + ' -> ' + UserDataDestPath);
|
|
ForceDirectories(UserDataDestPath);
|
|
CopyDir(UserDataBackupPath, UserDataDestPath);
|
|
Log('사용자 데이터 복원 완료');
|
|
end;
|
|
end;
|
|
end;
|